Integer BASIC

Integer BASIC is a BASIC interpreter written by Steve Wozniak for the Apple I and Apple II computers. Originally available on cassette for the Apple I in 1976, then included in ROM on the Apple II from its release in 1977, it was the first version of BASIC used by many early home computer owners.[2]

Integer BASIC
DeveloperSteve Wozniak
First appeared1976 (1976)[1]
PlatformApple I, Apple II
Influenced by
HP BASIC
Influenced
Applesoft BASIC

The only numeric data type was the integer; floating-point numbers were not supported. Using integers allowed numbers to be stored in a much more compact 16-bit format that could be more rapidly read and processed than the 32- or 40-bit floating-point formats found in most BASICs of the era. This made it so fast that Bill Gates complained when it outperformed Microsoft BASIC in benchmarks. However, this also limited its applicability as a general-purpose language.[lower-alpha 1]

Another difference with other BASICs of the era is that Integer BASIC treated strings as arrays of characters, similar to the system in C or Fortran 77. Substrings were accessed using array slicing rather than string functions. This style was introduced in HP Time-Shared BASIC, and could also be found in other contemporary BASICs patterned on HP, like North Star BASIC and Atari BASIC. It contrasted with the style found in BASICs derived from DEC, including Microsoft BASIC.

The language was initially developed under the name GAME BASIC and referred to simply as Apple BASIC when it was introduced on the Apple I. It became Integer BASIC when it was ported to the Apple II and shipped alongside Applesoft BASIC, a port of Microsoft BASIC which included floating-point support. Integer BASIC was phased out in favor of Applesoft BASIC starting with the Apple II Plus in 1979.

History

As a senior in high school, Steve Wozniak's electronics teacher arranged for the leading students in the class to have placements at local electronics companies. Wozniak was sent to Sylvania where he programmed in FORTRAN on an IBM 1130.[4] That same year, General Electric placed a terminal in the high school that was connected to one of their mainframes running their time-sharing BASIC service, which they were heavily promoting at the time. After being given three days of access, the students were asked to write letters on why the school should receive a terminal permanently, but their efforts were ultimately unsuccessful.[1]

Some years later, Wozniak was working at Hewlett-Packard (HP) running simulations of chip designs and logic layout for calculators.[1] HP made major inroads in the minicomputer market with their HP 2000 series machines running a custom timesharing version of BASIC. For approximately $100,000, one could build up a reasonably equipped machine that could support between 16 and 32 users running BASIC programs.[5] While expensive, it was still a fraction of the cost of the mainframe machines[lower-alpha 2] and, for heavy users, less than the timesharing services.[lower-alpha 3] HP followed this with the HP 9830, a desktop-sized machine for US$10,000 (equivalent to $75,000 in 2022) that also ran BASIC, which Wozniak had access to.[9]

I sniffed the wind and knew that the key to making my computer good (popular) was to include a high-level language and that it had to be BASIC.

Steve Wozniak[1]

In January 1975 the Altair 8800 was announced and sparked off the microcomputer revolution. In March, Wozniak attended the first meeting of the Homebrew Computer Club and began formulating the design of his own computer. One of the most important pieces of software for the Altair, and one of the most heavily pirated, was Altair BASIC from the recently formed Microsoft.[10] Wozniak concluded that his machine would have to have a BASIC of its own, which would, hopefully, be the first for the MOS Technology 6502 processor. As the language needed 4 KB RAM, he made that the minimum memory for the design.[1]

Wozniak's references for BASIC were a copy of 101 BASIC Computer Games and an HP BASIC manual.[1] He did not know that HP's BASIC was very different from the DEC BASIC variety used in 101 Games, which was also the basis of Microsoft BASIC for the Altair. Based on these sources, Wozniak began sketching out a syntax chart for the language. The design initially included floating-point support, but still hoping he might publish the first BASIC on the 6502 and become "a star", he decided to abandon floating-point and write a separate integer math system to save a few weeks programming time.[1]

Wozniak would later describe his language as "intended primarily for games and educational uses".[11] Referring to it throughout development as "GAME BASIC", Wozniak wrote the code by hand, translating the assembler code instructions into their machine code equivalents and then uploading the result to his computer.[12] Without any training on how to write a computer language, he used his HP calculator experience to implement a stack machine to interpret expressions. Once the basic routines were up and running, he worked on the other commands one-by-one in a modular fashion. With every visit to the Homebrew club, he demonstrated a few more features added in the last month.[1]

It was the most satisfying day of my life... I demonstrated Breakout [at Homebrew]-totally written in BASIC... After designing hardware arcade games, I knew that being able to program them in BASIC was going to change the world.

Steve Wozniak[9]

Ad for the Apple I computer noting Apple's policy of providing free or inexpensive software for its computers.

In early 1976 ads for its Apple I computer, Apple Inc made the claims that "our philosophy is to provide software for our machines free or at minimal cost"[13] and "yes folks, Apple BASIC is Free".[14] This was printed shortly after Bill Gates's infamous Open Letter to Hobbyists that suggested that people were robbing him by copying versions of Altair BASIC.[15]

Wozniak had helped Jobs, who worked for Atari, with a redesign of Breakout.[16] At some later point, he decided to see whether one could write the game in BASIC. He added commands to read paddle controllers and over a series of quick edits had a version of the game up and running. To improve its playability, he added a speaker to make clicks when the ball hit things. While showing it to Steve Jobs, Wozniak demonstrated that he could quickly change the colors that his game used, just by altering the source code. Wozniak later wrote that he had proved that "software was much more flexible than hardware", and that he and Jobs realized that "now, anyone could create arcade games without having to design it in hardware."[1]

Wozniak did complete a floating-point library for the 6502 and published it in the August 1976 edition of Dr. Dobb's Journal.[17] This library was later made part of the ROMs for the Apple II.[18] Wozniak began work on back-porting the floating-point code into Apple BASIC, but got sidetracked in the task of designing a floppy disk controller for what became the Disk II. Mike Markkula said the company would go to the Consumer Electronics Show in Las Vegas if the disk system was ready in time, so Wozniak and Randy Wigginton worked on it non-stop through the 1977 holidays.[19]

When he returned to the topic of floating-point in BASIC, Jobs complained it was taking too long. Without Wozniak being aware, the company had already arranged a license with Microsoft to receive their recently completed 6502 version of the Altair code. Examining the MS code, Wozniak decided that it was easier to add graphics support to their code than add floating-point his own BASIC, as the latter required hand-patching of the original machine code while MS's was written in assembler and more easily modified. The development of Apple's BASIC ended in favor of what became Applesoft BASIC. Wozniak later noted, "My biggest disappointment was going to the awful string functions like LEFT$(VAR, 5) and MID$(VAR2,5,3) instead of my own".[19][lower-alpha 4]

When the Apple II shipped in the summer of 1977, Integer BASIC was supplied in ROM, while Applesoft BASIC shipped on cassette. This changed with the introduction of the Apple II Plus in 1979, when Applesoft was put in the ROM.[20]

Description

Program editing

Like most BASIC implementations of the era, Integer BASIC acted as both the language interpreter as well as the line editing environment. When BASIC was running, a > command prompt was displayed where the user could enter statements.[21][lower-alpha 5] Unlike later home computer platforms, BASIC was not the default environment when the Apple I started, it normally started in the monitor. BASIC was started by pressing Ctrl+BReturn.[22]

Statements that were entered with leading numbers are entered into the program storage for "deferred execution",[23] either as new lines or replacing any that might have had the same number previously.[24] Statements that were entered without a line number were referred to as commands, and ran immediately.[lower-alpha 6] Line numbers could be from 0 to 32767,[25][lower-alpha 7] and lines could contain up to 128 characters.[27]

Integer BASIC also included the AUTO command to automatically enter line numbers at a given starting number like AUTO 100, adding 10 to the last number with every new line. AUTO 300,5 would begin numbering at line 300 by fives; 300, 305, etc. Automatic numbering was turned off by entering MAN.[28]

One interesting feature of the editor was that a section of the screen could be set aside as the "window", where live updates took place. This was normally the entire screen, but it could be limited to a smaller area by POKEing values into memory locations 32 through 35.[29] This feature could be used to create an editable text area while the rest of the screen was in graphics mode.[30]

Debugging

As in most BASICs, programs were started with the RUN command, and as was common, could be directed at a particular line number like RUN 300.[31] Execution could be stopped at any time using Ctrl+C[32] and then restarted with CONtinue, as opposed to the more typical CONT.[33]

For step-by-step execution, the TRACE instruction could be used at the command prompt or placed within the program itself. When it was turned on, line numbers were printed out for each line the program visited. The feature could be turned off again with NOTRACE.[34]

A somewhat unusual feature was the DSP (for "display") command. When encountered in a program, from that point on any changes to a variable's value would be displayed. For instance, DSP X would display the value of X every time it changed, along with the line number where the change occurred.[35] As with TRACE, DSP was turned off with NODSP.[26]

Variable names

Where Dartmouth BASIC and HP-BASIC limited variable names to at most two characters (either a single letter or a letter followed by one digit), and where MS-BASIC allowed a letter followed by an optional letter or digit (ignoring subsequent characters), Integer BASIC was unusual in supporting any length variable name (e.g., SUM, GAMEPOINTS, PLAYER2). The only caveat was that variable names could not contain reserved words; for example, THISCOLOR and COLORFUL were invalid variable names because they contained the keyword COLOR, a system command.[36] Additionally, lines were limited to 128 characters, so variable names could not exceed that length.[27]

Mathematics

Integer BASIC, as its name implies, uses integers as the basis for its math package. These were stored internally as a 16-bit number, little-endian (as is the 6502). This allowed a maximum value for any calculation between -32767 and 32767; although the format could also store the value -32768, BASIC could not display that number. Calculations that resulted in values outside that range produced a >32767 ERR.[37]

Infix operators included + (addition), - (subtraction), * (multiplication), / (division), MOD (remainder) and exponent using the ^ character. Binary operators included AND, OR and NOT. Binary comparisons included the standard set of =, >, <, >=, <=, <> and the HP-inspired #, which was equivalent to <>.[38]

Only single-dimension arrays were allowed, limited in size only by the available memory.[39] Mathematical functions were sparse; only ABS (absolute value), SGN (sign) and RND (random number) were supported.[40] In contrast to MS-derived versions, where the parameter was ignored and RND always returned a value 0..<1, Integer BASIC used the parameter; RND(6) returned an integer from 0 to 5.[41]

Strings

Integer BASIC's string handling was based on the system in HP BASIC. This treated string variables as arrays of characters which had to be DIMed prior to use. This is similar to the model in C[42] or Fortran 77.[43] This is in contrast to MS-like BASICs where strings are an intrinsic variable-length type.[44] Before MS-derived BASICs became the de facto standard, this style was not uncommon; North Star BASIC[45] and Atari BASIC[46] used the same concept, as did others.

Strings in Integer Basic used a fixed amount of memory regardless of the number of characters used within them, up to a maximum of 255 characters.[47] This had the advantage of avoiding the need for the garbage collection of the heap that was notoriously slow in MS BASIC[lower-alpha 8] but meant that strings that were shorter than the declared length was wasted.

Substring access was provided through array slicing syntax. For instance, PRINT A$(0,5) printed the first six characters of A$, characters 0 through 5.[49][49][lower-alpha 9] Concatenation was provided using the same system, A$(5)="ABC" replaced any characters starting at position 5 with the string "ABC".[50] This contrasts with the DEC/MS-style string handling which uses string functions like MID$ to access substrings and + for concatenation.[51][lower-alpha 10]

As many of the features that would be provided by string functions were instead provided by array slicing, the selection of string functions was reduced. LEN returned the length of a string[47] and ASC returned the ASCII numeric code for the first letter in a string.[52] It lacked an equivalent of the CHR$ that returned the ASCII character with a given numeric code.[53]

Graphics and sound

When launched, the only game controller for the Apple was the paddle controller, which had two controllers on a single connector. The position of the controller could be read using the PDL function, passing in the controller number, 0 or 1, like A=PDL(0):PRINT A, returning a value between 0 and 255.[54][lower-alpha 11]

The Apple machines did not include dedicated sound hardware, only a simple "beeper". Producing sounds was accomplished by PEEKing the memory-mapped location of the speaker, -16336.[lower-alpha 12] Repeatedly PEEKing that value produced tones, and the manual suggested using a mathematical expression to do this, like S=PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336).[56]

Support for graphics was more detailed. Graphics mode was turned on with the GR statement and off with TEXT.[57] Drawing was modal and normally started by issuing a command to change the color, which was accomplished by setting a pseudo-variable; COLOR=12 would set the drawing color to 12, light green. One could then PLOT 10,10 to produce a single spot of that color,[58] HLIN 0,39 AT 20 to draw a horizontal line at row 20 that spanned the screen, or VLIN 5,15 AT 7 to draw a shorter vertical line down column 7.[59] A=SCRN X,Y returned the color of the screen at X,Y.[52][lower-alpha 13]

Input/output

Integer BASIC lacked any custom input/output commands, and also lacked the DATA statement and the associated READ. To get data into and out of a program, the input/output functionality was redirected to a selected card slot with the PR#x and IN#x, which redirected output or input (respectively) to the numbered slot. From then on, data could be sent to the card using conventional PRINT commands and read from it using INPUT.[52]

Other notes

Integer BASIC included a TAB feature, which positioned the cursor on a given column from 0 to 39. It differed from the versions found in most BASICs in that it was a command with a following number, as opposed to a function with the value in parentheses; one would move the cursor to column 10 using TAB 10 in Integer BASIC[60] whereas in MS this would be PRINT TAB(10). Additionally, the VTAB command worked similar to TAB but added vertical spaces instead of horizontal. For unexplained reasons, in this case the coordinates were from 1 to 24 rather than 0 to 23.[61]

Integer BASIC included a POP command to exit from loops.[52] This popped the topmost item off the FOR stack. Atari BASIC also supported the same command,[62] while North Star BASIC used EXIT.[63]

The Integer BASIC ROMs also included a machine code monitor, "mini-assembler", and disassembler to create and debug assembly language programs. Wozniak hand-assembled the monitor as the Apple II's first program, then used it to write Integer BASIC.[64][65][2]

Apple BASIC

Apple BASIC had the following commands:[66]

AUTO val1, val2
CLR [CLEAR]
DEL val1, val2
LIST val1, val2
RUN val1
SCR [SCRATCH / NEW]
HIMEM = expr
LOMEM = expr
(LET) var = expr
INPUT (prompt,) var1, var2 ...
PRINT item(s)
TAB expr
FOR var = expr1 TO expr2 STEP expr3
NEXT var
IF expr THEN statement
IF expr THEN line number
GOTO expr
GOSUB expr
RETURN
DIM var1(expr1), var2(expr2) ...
REM text
END
POKE expr1, expr2
CALL expr
Functions: ABS(), SGN(), PEEK(), RND(), LEN()

Integer BASIC

Integer BASIC added the following:[67][68]

COLOR = expr
CON [CONTINUE]
DSP
GR
HLIN expr1, expr2 AT expr3
MAN
NEW [replaces SCR]
NOTRACE
PLOT expr1, expr2
POP
TEXT
TRACE
VLIN expr1, expr2 AT expr3
Function: ASC(), PDL(), SCRN(X,Y)

Implementation

Integer BASIC read the lines typed in by the user from a buffer and ran them through a parser which output a series of tokens. As part of this process, simple syntax errors were detected and listed. If the parsing was successful, the line number (if present) was converted from ASCII decimal format into a 16-bit integer and any keywords into a 7-bit integer token.[64]

Some keywords were represented by multiple tokens; for instance, where Microsoft BASIC had one token for the keyword PRINT, Integer BASIC had three tokens: one if the keyword was followed by no arguments, one if followed by an arithmetic expression, and one if followed by a string literal.[69]

Numeric literals, like the value 500, were converted into their 16-bit (two-byte) binary representation, in this case, $01F4 hexadecimal. To indicate this was a value and not a keyword, a single byte between $B0 and $B9 was inserted in front of the two-byte value.[lower-alpha 14] String literals, like "HELLO WORLD" were instead converted by setting the high bit of each character so that A was stored as $C1. Variable names were converted in the same fashion, with the letters converted to have their high-bit turned on, and any digits in the name represented by the corresponding $B0 through $B9, so that the variable A5 would be tokenized as $C1B5.[64]

If the line was entered without a line number, the code was then executed directly from the buffer. If it had a line number, it was copied from the buffer into the program storage area.[64]

The runtime interpreter used two stacks for execution: one for statement keywords and the other for evaluating the parameters. Each statement was given two priorities: one that stated where it should occur in a multi-step operation, like a string of mathematical operations to provide order of operations, and another that suggested when evaluation should occur, for instance, calculating internal values of a parentheses formula. When variables were encountered, their name was parsed and then looked up in the variable storage area. If it was not found, it was added to the end of the list. The address of the variable's storage, perhaps freshly created, was then placed on the evaluation stack.[64]

ROM details

SWEET16
Main article: SWEET16

In addition to Integer BASIC, the Apple ROMs contained a custom assembler language known as SWEET16. SWEET16 is based on bytecodes that run within a simple 16-bit virtual machine. This model was used so memory could be addressed via indirect 16-bit pointers and 16-bit math functions calculated without the need to translate those to the underlying multi-instruction 8-bit 6502 code. The entire virtual machine was written in only 300 bytes. Code can call SWEET16 by issuing a subroutine call, and then return to normal 6502 code when the 16-bit operations are complete.[70]

SWEET16 was not used by the core BASIC code, but was later used to implement several utilities. Notable among these was the line renumbering routine, which was included in the Programmer's Aid #1 ROM, added to later Apple II models and available for user installation on earlier examples.[71]

Floating point

Although Integer BASIC contained its own math routines, the Apple II ROMs also included a complete floating-point library located in ROM memory between $F425-$F4FB and $F63D-$F65D. The source code was included in the Apple II manual. BASIC programs requiring floating-point calculations could CALL into these routines.[72]

Performance

Because Integer BASIC processed more of the original source code into tokens, the runtime was faster than versions that required additional runtime parsing. For comparison, Tiny BASIC tokenized only the line number,[73] while MS BASICs tokenized only the keywords. So for instance, while Integer BASIC would convert the line 100 GOTO 200 entirely into tokens that could be immediately read and performed, in MS BASIC only the line number and GOTO would be tokenized, the "200" was left in its original ASCII format and had to be re-parsed into a 16-bit integer every time the line was encountered.[74]

Additionally, working solely with integer math provides another major boost in speed. This is due both to the smaller 16-bit format requiring fewer memory accesses, as well as removing the need to move the floating-point decimal after calculations. As many computer benchmarks of the era were small and often performed simple math that did not require floating-point, Integer BASIC trounced most other BASICs.[lower-alpha 15]

On one of the earliest known microcomputer benchmarks, the Rugg/Feldman benchmarks, Integer BASIC was well over twice as fast as Applesoft BASIC on the same machine.[76] In the Byte Sieve, where math was less important but array access and looping performance dominated, Integer BASIC took 166 seconds while Applesoft took 200.[77] It did not appear in the Creative Computing Benchmark, which was first published in 1983, by which time Integer BASIC was no longer supplied by default.[78]

The following test series, taken from both of the original Rugg/Feldman articles,[76][75] show Integer's performance relative to the MS-derived BASIC on the same platform.

SystemCPUBASICTest 1Test 2Test 3Test 4Test 5Test 6Test 7
Apple II6502 @ 1 MHzInteger BASIC1.33.17.27.28.818.528.0
Apple II6502 @ 1 MHzApplesoft BASIC1.38.516.017.819.128.644.8

Here is a summary of what each test did:

  • Test 1: simple loop to 1000.
  • Test 2: loop with compare to 1000.
  • Test 3: same as 2 with added multiplication, division, addition subtraction by same variable.
  • Test 4: same as 3 with added multiplication, division, addition subtraction by constants.
  • Test 5: same as 4 with added subroutine call.
  • Test 6; same as 5 with added inner loop.
  • Test 7: same as 6 with added table population.

Sample code

The following is a version of Breakout written in the 1977 version of Integer BASIC for the Apple II, which was listed in the Apple II Mini Manual.[79] There are a number of known bugs in this version.[80]

The program starts by setting the display to TEXT and then CALL -936 to clear the screen. Lines 20 through 27, and the associated subroutines at line 100 and 200, are the color selection code Wozniak demonstrated for Jobs. Line 30 sets up the text window with POKE 32,20[lower-alpha 16] and then uses a series of COLOR and VLIN statements to draw the playfield and the score display in the text window. The entire main loop runs from line 40 through 90 with associated subroutines. Another large amount of code near the end of the program is concerned with printing the final score. Other notes of interest include the # (not-equal) comparisons on line 20, the production of a high-pitch sound using a string of PEEKs on line 65 compared to a lower-pitched tone using a loop on line 70, and the mix of graphics and text on a single display.[lower-alpha 17]

5 TEXT: CALL -936: VTAB 4: TAB 10: PRINT "*** BREAKOUT GAME ***": PRINT
7 PRINT "  OBJECT IS TO DESTROY ALL BRICKS WITH 5 BALLS": FOR N=1 TO 7000: NEXT N
10 DIM A$(20),B$(20): GR: PRINT: INPUT "HI, WHAT'S YOUR NAME? ",A$:A=1:B=13:C=9:D=6:E=15: PRINT "STANDARD COLORS,"; A$;
20 INPUT "? ",B$: IF B$#"N" AND B$#"NO" THEN 30: FOR I=0 TO 39: COLOR=I/2*(I<32): VLIN 0,39 AT I
25 NEXT I: POKE 34,20: PRINT: PRINT: PRINT: FOR I=0 TO 15: VTAB 21+I MOD 2: TAB I+I+1: PRINT I;: NEXT I: POKE 34,22: VTAB 24: PRINT: PRINT "BACKGROUND";
27 GOSUB 100: A=E: PRINT "EVEN BRICK";: GOSUB 100: B=E: PRINT "ODD BRICK";: GOSUB 100: C=E: PRINT "PADDLE";: GOSUB 100: D=E : PRINT "BALL";: GOSUB 100
30 POKE34,20:COLOR=A:FORI=0TO39:VLIN0,39ATI:NEXTI:FOR I=20TO34STEP2:TAB I+1:PRINT I/2-9;:COLOR=B:VLIN 0,39 AT I:COLOR=C:FOR J=I MOD 4 TO 39 STEP4
35 VLIN J,J+1 AT I: NEXT J,I: TAB 5: PRINT "SCORE = 0": PRINT: PRINT: POKE 34,21: S=0: P=S: L=S: X=19: Y=19: X=19
40 COLOR=A:PLOTX,Y/3:X=19:Y=RND(120):V=-1:W=RND(5)-2:L=L+1:IFL>5THEN140:TAB6:PRINT"BALL #";L:PRINT:FORI=1TO100:GOSUB200:NEXTI:M=1:N=0
50 J=Y+W: IF J>=0 AND J<120 THEN 60: W=-W: J=Y: FOR I=1 TO 6: K=PEEK(-16336): NEXT I
55 IF PEEK(-16287)>127 THEN SW=1-SW
60 I=X+V: IF I<0 THEN 400: GOSUB 200: COLOR=A: K=J/3: IF I>39 THEN 70: IF SCRN(I,K)=A THEN 90: IF I THEN 120: N=N+1: V=(N>9)+1: W=(K-P)*2-5:M=1
65 Z = PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336): GOTO 90
70 FOR I=1 TO 6: M=PEEK(-16336): NEXT I: I=X: M=0
80 V=-V
90 PLOT X,Y/3: COLOR=E: PLOT I,K: X=I: Y=J: GOTO 50
99 PRINT "INVALID.  REENTER";
100 INPUT " COLOR (0 TO 15)",E: IF E<0 OR E>15 THEN 99: RETURN
120 IF M THEN V=ABS(V): VLIN K/2*2,K/2*2+1 AT I: S=S+I/2-9: VTAB 21: TAB 13: PRINT S
123 Q = PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)
124 IF S<720 THEN 80
130 PRINT "CONGRATULATIONS, YOU WIN.": GOTO 150
140 PRINT "YOUR SCORE OF ";S;" IS ";: GOTO 141+S/100
141 PRINT "TERRIBLE!": GOTO 150
142 PRINT "LOUSY.": GOTO 150
143 PRINT "POOR.": GOTO 150
144 PRINT "FAIR.": GOTO 150
145 PRINT "GOOD.": GOTO 150
146 PRINT "VERY GOOD.": GOTO 150
147 PRINT "EXCELLENT.": GOTO 150
148 PRINT "NEARLY PERFECT."
150 PRINT "SAME COLORS";: GOTO 20
200 IF SW THEN 220: Q=(PDL(0)-5)/6: IF Q<0 THEN Q=0
205 IF Q>=34 THEN Q=34: COLOR=D: VLIN Q,Q+5 AT 0: COLOR=A: IF P>Q THEN 210: IF Q THEN VLIN 0,Q-1 AT 0: P=Q: RETURN
210 IF P=Q THEN RETURN: IF Q#34 THEN VLIN Q+6,39 AT 0: P=Q: RETURN
220 Q=(Y-5)/3+RND(3)*SGN(W)*(X<10 AND V<0): IF Q<0 THEN Q=0: GOTO 205
400 FOR I=1 TO 80: Q=PEEK(-16336): NEXT I: GOTO 40

Notes
  1. Or as Bill Gates put it, "more powerful BASIC... using floating point".[3]
  2. An IBM 370/155 cost over $2 million in 1970 (equivalent to $15,000,000 in 2022).[6]
  3. Tymshare charged about $10 per hour (equivalent to $75 in 2022) for accessing their systems,[7] while smaller services could be found for about $5.[8]
  4. The string handling was not "his own", but the same system used by HP BASIC.
  5. To make it clear which BASIC was running, Applesoft used the ] prompt.
  6. In what MS referred to more descriptively as "immediate mode".
  7. Helmers says the lowest line number is 1.[26]
  8. And completely broken in some versions.[48]
  9. HP also allowed [ and ] in place of ( and ).
  10. It also contrasts with Dartmouth BASIC which used the CONVERT command to convert a string into an array of ASCII values which the user then manipulated and converted back to string format with a second CONVERT.
  11. The manual suggests, but does not outright state, that the actual range of values is less than 0 to 255.[54]
  12. The negative number is a side-effect of the integers being stored in signed format, so any memory location over 32767 appeared as a negative value in BASIC.[55]
  13. Note the odd syntax of the SCRN, which is technically a function because it returns a value, but does not use function-like syntax which would be A=SCRN(X,Y).
  14. The first digit of the original value was used to select a value from 0 to 9, so in this example, the token would be $B5 for the first digit of 500.
  15. Bill Gates complained about this, stating that it was unfair to compare Integer BASIC to a "real" BASIC like MS.[75]
  16. Meaning the text starts at line 20 of 24 lines on the screen, leaving four lines of text at the bottom.
  17. For a list of the various CALLs, PEEKs and POKEs that performed common operations on the Apple II, see Peeks, Pokes, Calls And Programming Notes, Charles Turley, 15 December 1996.

References

Citations
  1. Wozniak 2014.
  2. Weyhrich 2001.
  3. Rugg, Tom; Feldman, Phil (October 1977). "BASIC timing comparisons… revised and updated". Kilobaud. pp. 20–25.
  4. Baum, Allan (18 July 2016). "Oral History of Allen Baum" (Interview). Interviewed by David Brock. p. 12.
  5. "Passing the 10-year mark". MEASURE Magazine. Hewlett Packard. October 1976.
  6. Cooney, Michael. "The (mostly) cool history of the IBM mainframe". ARN.
  7. Bourne, Charles; Hahn, Trudi Bellardo (August 2003). A History of Online Information Services, 1963–1976. MIT Press. p. 387. ISBN 9780262261753.
  8. Barry, Tim (27 April 1981). "Back to BASIC". InfoWorld. p. 7.
  9. Williams & Moore 1984, p. A71.
  10. Fisk, Nathan (2009). Understanding Online Piracy. ABC-CLIO. p. 14. ISBN 9780313354748.
  11. Wozniak 1977.
  12. Weyhrich 2001, The [Integer] BASIC, which we shipped with the first Apple II's, was never assembled — ever. There was one handwritten copy, all handwritten, all hand-assembled..
  13. "The Apple 1 Project".
  14. "Apple I Computer Ad". 30 November 2009.
  15. Bunnell, David (September 1975). "Across the Editor's Desk". Computer Notes. Albuquerque NM.: MITS. 1 (4): 2. Archived from the original on March 23, 2012.
  16. "Classic Gaming: A Complete History of Breakout". GameSpy. Archived from the original on August 13, 2013. Retrieved April 19, 2010.
  17. Raskin, Roy; Wozniak, Steven (August 1976). "Floating Point Routines for the 6502". Dr. Dobb's. pp. 17–19.
  18. Apple II Reference Manual. Apple Computer. January 1978. pp. 94–95.
  19. Wozniak 2018.
  20. Hertzfeld 1985.
  21. Raskin 1978, p. 11.
  22. Raskin 1978, p. 12.
  23. Raskin 1978, p. 46.
  24. Raskin 1978, pp. 49–55.
  25. Raskin 1978, p. 48.
  26. Helmers 1978, p. 24.
  27. Raskin 1978, p. 118.
  28. Raskin 1978, pp. 65–67.
  29. Raskin 1978, p. 124.
  30. Wozniak 1977, "This mixed mode provides a 40 by 40 color graphics grid plus four lines of scrolling text at the bottom of the screen.".
  31. Raskin 1978, p. 100.
  32. Raskin 1978, p. 15.
  33. Raskin 1978, p. 52.
  34. Raskin 1978, p. 107.
  35. Raskin 1978, pp. 100, 101.
  36. Raskin 1978, p. 38.
  37. Raskin 1978, p. 27.
  38. Raskin 1978, p. 61.
  39. Raskin 1978, p. 94.
  40. Raskin 1978, p. 40,120.
  41. Raskin 1978, p. 40.
  42. "Strings". learn-c.org.
  43. Brooks, Steve. "Characters & Strings in Fortran" (PDF). University of Hawaii.
  44. "Integer, Floating Point and String Variables". C64 Programmer's Manual. Commodore.
  45. North Star BASIC version 6 (PDF). North Star Corporation. 1977. Archived from the original (PDF) on 2020-03-05. Retrieved 2020-03-03.
  46. The ATARI BASIC Reference Manual. Atari Inc. 1980. Archived from the original on 2005-05-01. Retrieved 2020-04-14.
  47. Raskin 1978, p. 89.
  48. "Create your own Version of Microsoft BASIC".
  49. Raskin 1978, p. 88.
  50. Raskin 1978, p. 92.
  51. altair 8080 basic manual (PDF). MITS. April 1977. p. 30.
  52. Raskin 1978, p. 120.
  53. Mini 1977, p. 17.
  54. Raskin 1978, p. 36.
  55. Mini 1977, p. 18.
  56. Raskin 1978, p. 84.
  57. Raskin 1978, p. 31.
  58. Raskin 1978, p. 32.
  59. Raskin 1978, p. 33.
  60. Raskin 1978, p. 73.
  61. Raskin 1978, p. 74.
  62. Atari BASIC Reference Manual (PDF). Atari. 1983. p. 25.
  63. North Star BASIC version 6 (PDF). North Star Corporation. 1977. p. 8. Archived from the original (PDF) on 2020-03-05. Retrieved 2020-03-03.
  64. Wozniak 1977, p. 42.
  65. Helmers 1978, p. 18.
  66. "PRELIMINARY APPLE BASIC USERS MANUAL". October 1976.
  67. "APPLE II BASIC PROGRAMMING MANUAL". 1978.
  68. "APPLE II REFERENCE MANUAL" (PDF).
  69. Paul R. Santa-Maria. "Apple II Integer Basic Disassembly" (PDF). Retrieved 2020-09-14.
  70. Wozniak 1977, p. 43.
  71. Apple Programmers Aid (PDF). Apple. 1978.
  72. Apple II Reference Manual (PDF). January 1978. pp. 94–95.
  73. Allison, Dennis (1976). "Build Your Own BASIC". Dr. Dobb's Journal. Vol. 1, no. 1. p. 11.
  74. Hardiman, Roger. "Altair BASIC 3.2 (4K) - Annotated Disassembly". p. 1.11. Archived from the original on 5 November 2001.
  75. Rugg, Tom; Feldman, Phil (October 1977). "BASIC timing comparisons… revised and updated". Kilobaud. pp. 20–25.
  76. Rugg, Tom; Feldman, Phil (June 1977). "BASIC Timing Comparisons… information for speed freaks". Kilobaud. pp. 66–70.
  77. Gilbreath, Jim (September 1981). "A High-Level Language Benchmark". Byte. p. 192.
  78. Ahl, David (November 1983). "Benchmark Comparison Test". Creative Computing. p. 260.
  79. Mini 1977, pp. 65–67.
  80. "Breakout, Annotated". GitHub. 16 August 2021.

Bibliography
This article is issued from Wikipedia. The text is licensed under Creative Commons - Attribution - Sharealike. Additional terms may apply for the media files.