EcosimPro

Differential equation
To familiarize yourself with the use of EcosimPro, first create a simple component to solve a differential equation. Although EcosimPro is designed to simulate complex systems, it can also be used independently of a physical system as if it were a pure equation solver. The example in this section illustrates this type of use. It solves the following differential equation to introduce a delay to variable x:

${\displaystyle {\frac {dy}{dt}}=(x-y)/tau}$

which is equivalent to

${\displaystyle y'=(x-y)/tau}$

where x and y have a time dependence that will be defined in the experiment. Tau is datum provided given by the user; we will use a value of 0.6 seconds. This equation introduces a delay in the x variable with respect to y with value tau. To simulate this equation we will create an EcosimPro component with the equation in it.

The component to be simulated in EL is like thus:

COMPONENT equation_test
   DATA
      REAL tau = 0.6      "delay time (seconds)"
   DECLS
      REAL x, y
   CONTINUOUS
      y' = (x - y) / tau
END COMPONENT

Pendulum
One example of applied calculus could be the movement of a perfect pendulum (no friction taken into account). We would have the following data: the force of gravity ‘g’; the length of the pendulum ‘L’; and the pendulum's mass ‘M’. As variables to be calculated we would have: the Cartesian position at each moment in time of the pendulum ‘x’ and ‘y’ and the tension on the wire of the pendulum ‘T’. The equations that define the model would be:

- Projecting the length of the cable on the Cartesian axes and applying Pythagoras’ theorem we get:

${\displaystyle x^{2}+y^{2}=L^{2}}$

By decomposing force in Cartesians we get

${\displaystyle F_{x}=-T{\frac {x}{L}}}$

and

${\displaystyle F_{y}=-T{\frac {y}{L}}-M\;g}$

To obtain the differential equations we can convert:

${\displaystyle F_{x}=M\;a_{x}=M\;{\ddot {x}}}$

and

${\displaystyle F_{y}=M\;a_{y}=M\;{\ddot {y}}}$

(note: ${\displaystyle {\dot {x}}}$ is the first derivative of the position and equals the speed. ${\displaystyle {\ddot {x}}}$ is the second derivative of the position and equals the acceleration)

This example can be found in the DEFAULT_LIB library as “pendulum.el”:

Modelling of a pendulum with EcosimPro

COMPONENT pendulum   "Pendulum example"
   DATA
      REAL g = 9.806               "Gravity (m/s^2)"
      REAL L = 1.                  "Pendulum longitude (m)"
      REAL M = 1.                  "Pendulum mass (kg)"
   DECLS
      REAL x                       "Pendulum X position (m)"
      REAL y                       "Pendulum Y position (m)"
      REAL T                       "Pendulum wire tension force (N)"
   CONTINUOUS
      x**2 + y**2 = L**2
      M * x'' = - T * (x / L)
      M * y'' = - T * (y / L) - M * g
END COMPONENT

The last two equations respectively express the accelerations, x’’ and y’’, on the X and Y axes