p-code machine

Compared to direct translation into native machine code, a two-stage approach involving translation into p-code and execution by interpreting or just-in-time compilation (JIT) offers several advantages.

• It is much easier to write a small p-code interpreter for a new machine than it is to modify a compiler to generate native code for the same machine.
• Generating machine code is one of the more complicated parts of writing a compiler. By comparison, generating p-code is much easier because no machine-dependent behavior must be considered in generating the bytecode. This makes it useful for getting a compiler up and running quickly.
• Since p-code is based on an ideal virtual machine, a p-code program is often much smaller than the same program translated to machine code.
• When the p-code is interpreted, the interpreter can apply additional run-time checks that are difficult to implement with native code.

One of the significant disadvantages of p-code is execution speed, which can sometimes be remedied via JIT compiling. P-code is often also easier to reverse-engineer than native code.

In the early 1980s, at least two operating systems achieved machine independence through extensive use of p-code. The Business Operating System (BOS) was a cross-platform operating system designed to run p-code programs exclusively. The UCSD p-System, developed at The University of California, San Diego, was a self-compiling and self-hosting operating system based on p-code optimized for generation by the Pascal language.

In the 1990s, translation into p-code became a popular strategy for implementations of languages such as Python, Microsoft P-Code in Visual Basic, and Java bytecode in Java.[4]

The language Go uses a generic, portable assembly as a form of p-code, implemented by Ken Thompson as an extension of the work on Plan 9 from Bell Labs. Unlike Common Language Runtime (CLR) bytecode or JVM bytecode, there is no stable specification, and the Go build tools do not emit a bytecode format to be used at a later time. The Go assembler uses the generic assembly language as an intermediate representation, and Go executables are machine-specific statically linked binaries.[5]

Niklaus Wirth specified a simple p-code machine in the 1976 book Algorithms + Data Structures = Programs. The machine had 3 registers - a program counter p, a base register b, and a top-of-stack register t. There were 8 instructions:

1. lit 0, a : load constant a
2. opr 0, a : execute operation a (13 operations: RETURN, 5 math functions, and 7 comparison functions)
3. lod l, a : load variable l, a
4. sto l, a : store variable l, a
5. cal l, a : call procedure a at level l
6. int 0, a : increment t-register by a
7. jmp 0, a : jump to a
8. jpc 0, a : jump conditional to a[6]

This is the code for the machine, written in Pascal:

const
	amax=2047;      {maximum address}
	levmax=3;       {maximum depth of block nesting}
	cxmax=200;      {size of code array}

type 
	fct=(lit,opr,lod,sto,cal,int,jmp,jpc);
	instruction=packed record 
		f:fct;
		l:0..levmax;
		a:0..amax;
	end;

var
	code: array [0..cxmax] of instruction;

procedure interpret;

  const stacksize = 500;

  var
    p, b, t: integer; {program-, base-, topstack-registers}
    i: instruction; {instruction register}
    s: array [1..stacksize] of integer; {datastore}

  function base(l: integer): integer;
    var b1: integer;
  begin
    b1 := b; {find base l levels down}
    while l > 0 do begin
      b1 := s[b1];
      l := l - 1
    end;
    base := b1
  end {base};

begin
  writeln(' start pl/0');
  t := 0; b := 1; p := 0;
  s[1] := 0; s[2] := 0; s[3] := 0;
  repeat
    i := code[p]; p := p + 1;
    with i do
      case f of
        lit: begin t := t + 1; s[t] := a end;
        opr: 
          case a of {operator}
            0: 
              begin {return}
                t := b - 1; p := s[t + 3]; b := s[t + 2];
              end;
            1: s[t] := -s[t];
            2: begin t := t - 1; s[t] := s[t] + s[t + 1] end;
            3: begin t := t - 1; s[t] := s[t] - s[t + 1] end;
            4: begin t := t - 1; s[t] := s[t] * s[t + 1] end;
            5: begin t := t - 1; s[t] := s[t] div s[t + 1] end;
            6: s[t] := ord(odd(s[t]));
            8: begin t := t - 1; s[t] := ord(s[t] = s[t + 1]) end;
            9: begin t := t - 1; s[t] := ord(s[t] <> s[t + 1]) end;
            10: begin t := t - 1; s[t] := ord(s[t] < s[t + 1]) end;
            11: begin t := t - 1; s[t] := ord(s[t] >= s[t + 1]) end;
            12: begin t := t - 1; s[t] := ord(s[t] > s[t + 1]) end;
            13: begin t := t - 1; s[t] := ord(s[t] <= s[t + 1]) end;
          end;
        lod: begin t := t + 1; s[t] := s[base(l) + a] end;
        sto: begin s[base(l)+a] := s[t]; writeln(s[t]); t := t - 1 end;
        cal: 
          begin {generate new block mark}
            s[t + 1] := base(l); s[t + 2] := b; s[t + 3] := p;
            b := t + 1; p := a
          end;
        int: t := t + a;
        jmp: p := a;
        jpc: begin if s[t] = 0 then p := a; t := t - 1 end
      end {with, case}
  until p = 0;
  writeln(' end pl/0');
end {interpret};

This machine was used to run Wirth's PL/0, a Pascal subset compiler used to teach compiler development.[7]

P-Code is a name for several of Microsoft's proprietary intermediate languages. They provided an alternate binary format to machine code. At various times, Microsoft have said p-code is an abbreviation for either packed code[8] or pseudo code.[9]

Microsoft p-code was used in Visual C++ and Visual Basic. Like other p-code implementations, Microsoft p-code enabled a more compact executable at the expense of slower execution.

• Bytecode
• Intermediate representation
• Joel McCormack, designer of the NCR Corporation version of the p-code machine
• Runtime system
• Token threading
• City & Guilds Mnemonic Code
• Platform-independent model – Software engineering model

• Pemberton, Steven; Daniels, Martin. Pascal Implementation: The P4 Compiler and Interpreter. John Wiley. ISBN 0-13-653031-1.
• Pemberton, Steven, ed. (2011-04-13). "Pascal Implementation: A Book and Sources". (NB. Has Pascal sources of the P4 compiler and interpreter, usage instructions.)
• Pemberton, Steven, ed. (2011-04-13). "pcode of the Pascal Compiler as compiled by itself". (NB. Has the p-code of the P4 compiler, generated by itself.)
• "The Jefferson Computer Museum's page on the UCSD p-System".
• "Open Source implementation"., including packaging and pre-compiled binaries; a friendly fork of the Klebsch. "Klebsch implementation".
• Terry, Pat (2005). Compiling with C# and Java. p. 624. ISBN 0-321-26360-X.
• Wirth, Niklaus (1975). Algorithms + Data Structures = Programs. ISBN 0-13-022418-9.
• Wirth, Niklaus (1996). Compiler Construction. ISBN 0-201-40353-6.
• Liffick, Blaise W., ed. (1979). The Byte Book of Pascal. ISBN 0-07-037823-1.
• Barron, David William, ed. (1981). Pascal: The Language and its Implementation. ISBN 0-471-27835-1. (NB. Especially see the articles Pascal-P Implementation Notes and Pascal-S: A Subset and its Implementation.)

• VB P-code Information by Mr Silver at the Wayback Machine (archived December 22, 2015)