TI-BASIC

Control flow statements include if-then-else blocks, for loops, while loops, and repeat loops, though no switch statements. The main control flow statements are:

 If condition
 Then
 ...
 Else
 ...
 End

 For(variable,start,stop,step)
 ...
 End

 While condition
 ...
 End

 Repeat condition
 ...
 End

Unusual for a high level language, TI-BASIC implementations include IS> (Increment and Skip if Greater Than) and DS< (Decrement and Skip if Less Than) statements, constructs generally associated with assembly languages. Sections of programs can be labeled; however, particularly on the Z80 models, the labels function as destinations for Goto statements or Menu( functions rather than as program or block labels.

Availability of functions and subroutines depends on the implementation; the versions available on the TI-82-descended calculators do not even support a GOSUB-like function, though it is possible to call programs from within each other and share variables between programs. TI-89/92-based designs can have access to shared functions, essentially programs capable of returning a value.

TI-BASIC is a strongly and dynamically typed language. Available data types differ considerably between the 68k and Z80 versions. It is not possible to create user-defined data types without using a library written in assembly. Lists are often used as a replacement for structs.

• Numerical variables, including A - Z and θ (theta). These allow real numbers or complex numbers (implemented as pairs of reals) to be stored in floating point format. Values may range from 1E-99 to 1E99 with up to ten digits of accuracy. The limit of 27 variables, however, may be expanded through the use of lists, matrices, and manipulation of integer notation. A list or matrix can be used to contain unique real variables which can be individually referenced. Integers can be concatenated into a single real variable by delineating them as the integer and decimal halves of a real number; each half is then accessed independently via the iPart and fPart commands. Variables with binary values can be stored as a single integer through conversion between base 2 and base 10.
• Strings, including Str0 - Str9. These may store any number of characters or even function names, as long as there is available memory. They can be evaluated as an expression with the expr() function, which is found in the catalog.
• Lists, including L1 - L6, with the ability to create additional ones. These are essentially one-dimensional arrays used to store a real or complex number into each of their elements. The dimension of a list, its number of elements, may range from 1 to 999, although available memory may be a limiting factor. When a list's dimension is set lower than it had been, elements at the end are cut off. When set higher, extra elements at the end are filled with zeros. Dimensions are set by storing a valid number into the dim( of the list name. The default lists are named L1–L6, but custom lists can be created. This is done by setting dimension of a list referenced with the L token in the Lists, followed by a name ranging from 1 to 5 characters that begins with an uppercase letter A - Z and θ. Individual elements of lists can be accessed by placing the element number in parentheses after the list name.
• Matrices, including [A] - [J]. Their elements are subject to the same restrictions as lists. Their dimensions may be defined up to 99x99 elements, although, again, available memory will limit this. It is not possible to create user-defined matrices, so only the ten built in ones may be utilized.
• Equation variables, including Y0 - Y9, r1 - r6, and u, v, w. These are essentially strings which store equations. They are evaluated to return a value when used in an expression or program. Specific values, (constant, C) can be plugged in for the independent variable (X) by following the equation name (dependent, Y) by the constant value in parentheses. In the example below, "(4)" is used (for no particular reason). (Y1(4) would return the value of Y1 at X=4)

Data types that cannot be directly manipulated include:

• Pictures (Pic0 - Pic9)
• Background (Image0 - Image9)
• Programs (prgm)
• Graph databases (GDB0 - GDB9)
• Color (BLUE, RED,..., GRAY) (15 colors in total)

• Integers, which can store a large amount of data. The 68k calculators can store very large numbers, as high as ${\displaystyle 10^{600}}$, with perfect accuracy.
• Real numbers, using decimal floating point. These store up to 14 significant digits depending on the calculator model.
• Complex numbers, implemented as pairs of reals.
• Strings
• Lists, which are one-dimensional linked lists which support element-wise operations. On the 68k calculators, elements can be integers, reals, complex numbers, strings or expressions.
• Matrices, with elements subject to the same restrictions in lists
• Symbolic expressions, unique to the 68k series.

Data types that cannot be directly manipulated (typing only their name on a line would result in an error) include:

• Pictures
• Data
• Programs
• Functions

Flexibility in the use of variables varies widely by the calculator model. For example, on the TI-84 Plus, all English language letters as well as theta (Θ) are available.

On the TI-83/84, the programmer can create lists whose names are up to five characters. All other data types are limited, such as the 27 real or complex variables, and a number of predefined variable names of other types (e.g., matrices have to be one of the ten variables [A]-[J]). On the TI-83/84 certain variables such as Ans and the finance variables have fixed addresses in RAM, making them much faster to access than the 27 letter variables. Ans acts as a special variable containing the result of the last evaluated code. A line with just a variable will still be evaluated and its contents stored in Ans as a result. Because Ans is reevaluated so frequently it most often is used to store very temporary calculations or to hold values that would otherwise be slow to access such as items from a list. All variables are global.

In contrast, 68k calculators allow all variable names to have up to eight alphanumeric characters, including Greek. Furthermore, variables can be grouped into "folders", or made local to a program by declaring them with the Local statement.

Z80 programmers often start lines with " (double quotation mark) to denote a comment. Lines starting with " are actually executed changing the Ans variable, but this does not affect anything other than performance unless Ans is read immediately afterwards.

The 68k calculators allow programs to include single-line comments, using © as a comment symbol. If a comment appears as the first line after the "Prgm" statement, it is displayed in the status bar when the program is selected in the catalog; such comments are often used to document the names or types of parameters. The 68k interpreter has a built in feature to store the number of space characters at the beginning of a line, this allows indentation.

The Z80 version of TI-BASIC makes explicit "functions" like those in 68k impossible. However, all variables are global so functions can be emulated by setting variables, similar to arguments, before calling another program. Return values do not exist; the Return statement stops the current program and continues where the program was called.

The 68k version of TI-BASIC allows creating user-defined functions. Functions have the same syntax as programs except that they use the Func...EndFunc keywords instead of Prgm...EndPrgm, and that they are not allowed to use instructions that perform I/O, modify non-local variables, nor call programs. However, functions can still be non-pure because they can call built-in functions such as getTime(), getKey(), or rand(). All functions have a return value, which in the absence of an explicit Return statement is the last expression evaluated.

Third-party applications, in chronological order Omnicalc,[5] xLIB,[6] Celtic, and Doors CS,[7] have overloaded TI-BASIC functions on the Z80 calculators to provide additional language functionality. The third-party libraries overload the sum(), real(), det() and identity() functions, which are handled and interpreted by their respective applications. Among the extra functions are fast shape-drawing routines, sprite and tilemap tools, program and VAT modification and access abilities, GUI construction features, and much more, most of which are ordinarily restricted to use by assembly programmers. All of the functions require that an application like Doors CS 7.0 be present on the user's calculator, sometimes considered a detraction to the use of the libraries.

The following programs, when executed, will display the phrase "HELLO, WORLD!".

:Disp "HELLO, WORLD!"

(P.S. this code can be shortened down to just the Disp function, like in the TI-83/84, and the hellowld, prgm, and endprgm are auto-generated.)

:hellowld()
:Prgm
:ClrIO
:Disp "HELLO, WORLD!"
:Pause
:ClrIO
:DispHome
:EndPrgm

text "HELLO, WORLD!"

text "HELLO, WORLD!"

PROGRAM:LISTS
:"ASK FOR THE NUMBER OF VARIABLES
:Input "NUMBER OF VARS? ",A
:"VALIDATE INPUT OR STOP
:If A<1 or fPart(A)
:Stop
:"A FOR LOOP TO ASK FOR EACH VALUE TO BE IN THE LIST
:For(N,1,A)
:Input "VAR ",B
:"STORE THE VALUE INTO THE NTH ELEMENT
:B→L1(N)
:End
:"IMPLICITLY RETURN THE FINAL LIST
:L1

lists()
:Prgm
:  Local n,i,c © Declare local variables n, i, and c.
:  {}→list © Initialize list as an empty list.
:  Input "Number of variables?",n 
:  For i,1,n
:    Input "Variable #"&string(i),c © & concatenates i after it is converted to a string.
:    c→list[i]
:  EndFor
:EndPrgm

Lists have many possible names, this allows for many programs to manipulate many lists without overriding previous data. Lists on the TI-82 cannot have custom names (L₁ through L₆ are preprogrammed). The TI-85 and TI-86 do not have the ability to handle a variable name with subscripts. The TI-81 is completely unable to handle lists. Lists can be used by the numerous built-in TI-BASIC functions for calculating statistics, including various regression analyses and more.[1] These can be called inside of programs, however they still show the info while pausing execution and they cannot store specific results into variables.

Recursion is possible. A program can be called from within itself or from within another program.

The example below is used to compute factorials. In order for it to work, X is the parameter of the factorial function and A must equal 1.

PROGRAM:FACT
:If X=0
:Then
:Disp A
:Stop
:End
:XA→A
:X-1→X
:prgmFACT

factui()
:Prgm
:  Local n
:  Define fact(x)=Func
:    If x=0
:      Return 1
:    Return x*fact(x-1)
:  EndFunc
:  Input "Input a number", n
:  Disp "n! = "
:  Disp fact(n)
:EndPrgm

The 68k series makes a distinction between programs and functions. Functions are just like programs except that they do not allow statements that perform I/O, including modifying non-local variables, and they return a value, which in the absence of an explicit Return statement is the last expression evaluated.

fact(x)
:Func
:  If x=0
:    Return 1
:  If x<0
:    Return undef
:  x*fact(x-1)
:End Func