Comment construire un robot chez soi

#include <Servo.h>

Servo leftMotor;
Servo rightMotor;

const int serialPeriod = 250;       // cela limite les sorties de console à tous les quarts de seconde
unsigned long timeSerialDelay = 0;

const int loopPeriod = 20;          // cela fixe la fréquence de lecture du détecteur à 20 ms, ce qui correspond à une fréquence de 50 Hz
unsigned long timeLoopDelay   = 0;

// Cela assigne les fonctions TRIG et ECHO aux fiches de l’Arduino. Ajustez les numéros si vous avez choisi des fiches différentes
const int ultrasonic2TrigPin = 8;
const int ultrasonic2EchoPin = 9;

int ultrasonic2Distance;
int ultrasonic2Duration;

// cela définit les deux états possibles du robot : marche avant ou virage à gauche
#define DRIVE_FORWARD     0
#define TURN_LEFT         1

int state = DRIVE_FORWARD; // 0 = drive forward (DEFAULT), 1 = turn left

void setup()
{
    Serial.begin(9600);
  
    // configuration des fiches du détecteur
    pinMode(ultrasonic2TrigPin, OUTPUT);
    pinMode(ultrasonic2EchoPin, INPUT);
    
    // assignation des moteurs aux fiches de l’Arduino
    leftMotor.attach(12);
    rightMotor.attach(13);
}


void loop()
{
    if(digitalRead(2) == HIGH) // cela permet de détecter le bouton
    {
        while(1)
        {
            leftMotor.write(90);
            rightMotor.write(90);
        }
    }

    debugOutput(); // cela permet d’imprimer des messages pour le débogage éventuel sur la console
    
    if(millis() - timeLoopDelay >= loopPeriod)
    {
        readUltrasonicSensors(); // cela demande au détecteur de lire les données et de stocker les distances mesurées
        
        stateMachine();
        
        timeLoopDelay = millis();
    }
}


void stateMachine()
{
    if(state == DRIVE_FORWARD) // si aucun obstacle détecté
    {
        if(ultrasonic2Distance > 6 || ultrasonic2Distance < 0) // s'il n’y a rien devant le robot. ultrasonicDistance sera négative pour certains détecteurs s'il n’y a pas d’obstacle détecté
        {
            // drive forward
            rightMotor.write(180);
            leftMotor.write(0);
        }
        else //  si un obstacle est détecté
        {
            state = TURN_LEFT;
        }
    }
    else if(state == TURN_LEFT) // si l’obstacle est détecté, tourne à droite
    {
        unsigned long timeToTurnLeft = 500; // il faut 0,5 seconde pour tourner de 90 degrés. Vous devriez ajuster ce nombre si la taille des roues que vous avez choisies est différente
        
        unsigned long turnStartTime = millis(); // enregistre le début de rotation des roues

        while((millis()-turnStartTime) < timeToTurnLeft) // reste dans la boucle jusqu’à ce que timeToTurnLeft soit terminé
        {
            // tourne à gauche, n’oubliez pas que les deux roues sont réglées à 180 pour tourner
            rightMotor.write(180);
            leftMotor.write(180);
        }
        
        state = DRIVE_FORWARD;
    }
}


void readUltrasonicSensors()
{
    // c’est pour ultrasonic 2. Vous devez changer cette commande si vous avez un détecteur différent
    digitalWrite(ultrasonic2TrigPin, HIGH);
    delayMicroseconds(10);                  // gardez la fiche trig en position high pendant au moins 10 microsecondes
    digitalWrite(ultrasonic2TrigPin, LOW);
    
    ultrasonic2Duration = pulseIn(ultrasonic2EchoPin, HIGH);
    ultrasonic2Distance = (ultrasonic2Duration/2)/29;
}

// ce code permet de déboguer le programme dans la console.
void debugOutput()
{
    if((millis() - timeSerialDelay) > serialPeriod)
    {
        Serial.print("ultrasonic2Distance: ");
        Serial.print(ultrasonic2Distance);
        Serial.print("cm");
        Serial.println();
        
        timeSerialDelay = millis();
    }
}